>>  <<  Ркв  Ввд  JfC  LJ  Фрз  Слв  Изм  Рзг  !:  Помощь  Словарь

5. Вилки

Как мы уже видели, изолированная последовательность трех глаголов называется вилкой; ее монадный и диадный случаи определены как:

       g
 / \
f   h
|   |
y   y 		         g
   / \
  f   h
 / \ / \
x  y x  y

Приведенные выше диаграммы дают визуальную иллюстрацию вилки.

Не читая комментариев справа (используя тот факт, что %: обозначает взятие корня, а ] тождественную функцию), попробуйте выразить на русском значение каждого из следующих предложений:

   a=: 8 7 6 5 4 3
   b=: 4 5 6 7 8 9
   2 %: b                     Квадратный корень b
2 2.23607 2.44949 2.64575 2.82843 3
                
   3 %: b                     Кубический корень b
1.5874 1.70998 1.81712 1.91293 2 2.08008
                
   (+/ % #) b                 Среднее арифметическое, или просто "среднее"
6.5
           
   (# %: */) b                Среднее геометрическое
6.26521

   (] - (+/ % #)) b           Центрировать вокруг среднего (две вилки)
_2.5 _1.5 _0.5 0.5 1.5 2.5

   (] - +/ % #) b             Две вилки (меньше скобок)
_2.5 _1.5 _0.5 0.5 1.5 2.5

  
   a (+ * -) b                Диадный случай вилки
48 24 0 _24 _48 _72

   (a^2)-(b^2)
48 24 0 _24 _48 _72
                
   a (< +. =) b               Меньше или равно
0 0 1 1 1 1
  
   a<b
0 0 0 1 1 1

   a=b
0 0 1 0 0 0

   a (<: = < +. =) b          Тавтология(<: есть меньше либо равно)
1 1 1 1 1 1
  
   2 ([: ^ -) 0 1 2           Шапка дает монадный случай
7.38906 2.71828 1 

   evens=: [: +: i.           +:  удваивает
   evens 7
0 2 4 6 8 10 12

   odds=: [: >: evens         >:  прибавляет 1
   odds 7
1 3 5 7 9 11 13

Упражнения

5.1   Введите 5#3 и подобные выражения для исследования диады # . Затем опишите значение следующего предложения: 
(# # >./) b=: 2 7 1 8 2
Ответ: #b повторений максимума в b

5.2   Закройте комментарии справа, запишите собственные интерпретации каждого предложения, сравните:
(+/ % #) b                    Среднее по b
(# # +/ % #) b                (n=:#b) повторений среднего
+/(##+/%#) b                  Сумма n средних
(+/b)=+/(##+/%#) b            Тавтология
(*/b)= */(###%:*/) b          Произведение элементов b есть произведение n
                              повторений среднего геометрического b


>>  <<  Ркв  Ввд  JfC  LJ  Фрз  Слв  Изм  Рзг  !:  Помощь  Словарь